Move ListBox Items Up & Down

Got any Excel/VBA Questions? Free Excel Help

Change Order Of List Box Values

Add 2 CommandButtons to your UserForm and Name them MoveUp and MoveDown. Then, use the RowSource Property of the Multi Column ListBox to fill the ListBox with a Named Range. Ensure this named range has headings BUT are no included in the range name definition. Set the ColumnHeads Property of the ListBox to True and the ColumnCount to as many columns as the named range has Columns. Set the ColumnWidths as needed.

Private Sub MoveDown_Click() 

    Dim lCurrentListIndex As Long 

    Dim strRowSource As String 

    Dim strAddress As String 

    Dim strSheetName As String 

     

     

    With ListBox1 

        If .ListIndex < 0 Or .ListIndex = .ListCount - 1 Then Exit Sub 

        lCurrentListIndex = .ListIndex + 1 

        strRowSource = .RowSource 

        strAddress = Range(strRowSource).Address 

        strSheetName = Range(strRowSource).Parent.Name 

        .RowSource = vbNullString 

        With Range(strRowSource) 

            .Rows(lCurrentListIndex).Cut 

            .Rows(lCurrentListIndex + 2).Insert Shift:=xlDown 

        End With 

         Sheets(strSheetName).Range(strAddress).Name = strRowSource 

        .RowSource = strRowSource 

        .Selected(lCurrentListIndex) = True 

    End With 

     

End Sub 

 

Private Sub MoveUp_Click() 

    Dim lCurrentListIndex As Long 

    Dim strRowSource As String 

    Dim strAddress As String 

    Dim strSheetName As String 

     

     

    With ListBox1 

        If .ListIndex < 1 Then Exit Sub 

        lCurrentListIndex = .ListIndex + 1 

        strRowSource = .RowSource 

        strAddress = Range(strRowSource).Address 

        strSheetName = Range(strRowSource).Parent.Name 

        .RowSource = vbNullString 

        With Range(strRowSource) 

            .Rows(lCurrentListIndex).Cut 

            .Rows(lCurrentListIndex - 1).Insert Shift:=xlDown 

        End With 

        Sheets(strSheetName).Range(strAddress).Name = strRowSource 

        .RowSource = strRowSource 

        .Selected(lCurrentListIndex - 2) = True 

    End With 

     

End Sub

Download Example